自作パワーディメンションコマンドLISP

;;=================================================================
;; 寸法タイプ判定（DXF100 の最後）
;;=================================================================
(defun getDimClass (ent / dxf last100)
  (setq dxf (entget ent)
        last100 nil)
  (foreach x dxf
    (if (= (car x) 100)
      (setq last100 (cdr x))
    )
  )
  last100
)

;;=================================================================
;; メインコマンド PD
;; 寸法記入 + DIMSPACE 専用
;;=================================================================
(defun c:PD (/ baseEnt base-list oldlast new p1 p2 first done tmp
              oldDimLayer cmd dimclass)

  (vl-load-com)

  (prompt "\n=== 寸法記入 + DIMSPACE 専用 ===")

  ;;=======================================================
  ;; 寸法用レイヤー設定
  ;;=======================================================
  (setq oldDimLayer (getvar "DIMLAYER"))

  (if (not (tblsearch "LAYER" "SUNPOU"))
    (command "_.LAYER" "_M" "SUNPOU" "_C" "7" "" "")
  )

  (setvar "DIMLAYER" "SUNPOU")

  ;;=======================================================
  ;; 基準寸法選択
  ;; クリックした瞬間に確定
  ;;=======================================================
  (prompt "\n[DMSP] 基準寸法をクリックしてください。")
  (setq baseEnt (car (entsel "\n基準寸法を選択: ")))

  (if (or
        (null baseEnt)
        (/= (cdr (assoc 0 (entget baseEnt))) "DIMENSION")
      )
    (progn
      (prompt "\n寸法が選択されませんでした。終了します。")
      (setvar "DIMLAYER" oldDimLayer)
      (princ)
      (exit)
    )
  )

  (setq base-list (list baseEnt))

  ;;=======================================================
  ;; 基準寸法タイプを判定
  ;;=======================================================
  (setq dimclass (getDimClass (car base-list)))

  (cond
    ((= dimclass "AcDbAlignedDimension")
      (setq cmd "_.DIMALIGNED")
      (prompt "\n基準寸法：平行寸法 → DIMALIGNED")
    )

    ((= dimclass "AcDbRotatedDimension")
      (setq cmd "_.DIMLINEAR")
      (prompt "\n基準寸法：線形寸法 → DIMLINEAR")
    )

    (T
      (setq cmd "_.DIMLINEAR")
      (prompt
        (strcat
          "\n基準寸法タイプ不明("
          (if dimclass dimclass "nil")
          ") → DIMLINEAR"
        )
      )
    )
  )

  ;;=======================================================
  ;; 寸法作図ループ
  ;;=======================================================
  (setq first T
        done nil)

  (while (not done)

    (if first

      ;;===========================================
      ;; 初回寸法
      ;; 寸法位置は1点目 p1 を自動指定
      ;;===========================================
      (progn
        (setq p1 (getpoint "\n1点目を指定 : "))
        (if (null p1) (setq done T))

        (if (not done)
          (progn
            (setq p2 (getpoint "\n2点目を指定: " p1))
            (if (null p2) (setq done T))
          )
        )

        (if (not done)
          (progn
            (setq oldlast (entlast))

            ;; 寸法作図
            ;; 3点目の寸法位置は p1 を自動入力
            (command cmd p1 p2 p1)
            (setq new (entlast))

            ;; DIMSPACE 実行
            (command "_.DIMSPACE")
            (foreach b base-list
              (command b)
            )
            (command new)
            (command "")
            (command "")

            (setq first nil)
          )
        )
      )

      ;;===========================================
      ;; 2回目以降：直列寸法
      ;;===========================================
      (progn
        (prompt "\n直列寸法を続ける点をクリック : ")

        (setq oldlast (entlast))
        (command "_.DIMCONTINUE" pause)
        (setq tmp (entlast))

        ;; Enterで終了
        (if (= tmp oldlast)
          (setq done T)
          (setq new tmp)
        )
      )
    )
  )

  ;;=======================================================
  ;; DIMLAYER 元に戻す
  ;;=======================================================
  (setvar "DIMLAYER" oldDimLayer)

  (prompt "\n処理を終了しました。")
  (princ)
)